@echo off
:: make_web_index.btm
  *setlocal
  *unalias *
  ::on error goto done
  on break goto done

if "%1"=="" goto usage
if not exist %1 goto path_not_found
set full_path=%@path["%@full["%0"]"]
set dest_path=%@path["@full["%1"]"]
if not exist "%full_path%down.gif" goto GIF_NOT_FOUND
if not exist "%dest_path%down.gif" copy "%full_path%down.gif" "%dest_path%down.gif"

goto start

:GIF_NOT_FOUND
echo.
echo unable to find "%full_path%down.gif"
goto done

:PATH_NOT_FOUND
echo.
echo Unable to find path: %1

:usage
echo.
echo Usage: %0 path [path] [title] [suppress]
echo.
echo path     - Path from which to build the index
echo title    - Title of the web page
echo suppress - Files to not include in the list. Default is "*.php *.htm* *.bak *~"
echo.
goto done

:start
  set f="index.php"
  rem set suppress=/[!*.ion index*.htm *.ba*]
  set suppress=/[!*.php *.htm* *.bak *~]
  set d="%@full[%1]"
  set based=%@filename[%d]
  set title=%@strip[%=",%2]
  if ".%title."==".." set %title=%d
  if not ".%3."==".." set suppress=/[!%@strip[%=",%3]]
  echo %=nUsage: %0 path [path] [title] [suppress]
  echo %=n%@upper[%0]:  Hit Ctrl-C to abort or press any key to
  pause %@if[exist %f,re,]build %f from %d.
  cdd %d
  >!%f
  echo %=<HTML%=>%=<HEAD%=> >> %f
  echo %=<TITLE%=>%title%=</TITLE%=> >> %f
  echo %=</HEAD%=> >> %f
  echo %=<BODY%=> >> %f
  echo %=<CENTER%=> >> %f
  echo %=<H1%=>%title%=</H1%=> >> %f
  echo %=<P%=> >> %f

text >> %f
<CENTER>
<P>
<INPUT type="button" value="Click here to go back" onClick="history.back()"/>
</P>
</CENTER>
<TABLE ALIGN=CENTER BORDERCOLOR="#0000FF" BORDER="5" WIDTH="98%">
<TR>
<TD BGCOLOR="WHITE"><CENTER><B>Name</B></CENTER></TD>
<TD BGCOLOR="WHITE"><CENTER><B>Date</B></CENTER></TD>
<TD BGCOLOR="WHITE"><CENTER><B>Download</B></CENTER></TD>
<TD BGCOLOR="WHITE"><CENTER><B>Description</B></CENTER></TD>
</TR>
endtext

  set n=0
  dir %suppress /a:-d /b > clip:
  for %ii in (@clip:) (
    echo %=<TR%=> >> %f

    iff exist "%ii%.html" then (
        echo %=<TD%=>%=<A HREF="%ii%.html"%=>%ii%=</A%=>%=</TD%=> >> %f
    )
    else
        echo %=<TD%=>%ii%=</TD%=> >> %f
    endiff

    echo %=<TD ALIGN=CENTER%=>%@filedate["%ii",w,4]%=</TD%=> >> %f
    echo %=<TD ALIGN=CENTER%=>%=<A HREF="%ii"%=>%=<IMG ALT="get" BORDER="0" SRC="down.gif"/%=>%=</A%=> %@format[5,%@filesize["%ii",K]]K%=</TD%=> >> %f
    set base_name=%@LEFT[%@index[%ii,.],%ii]
    set description=%@descript["%ii"]
    if "%description"=="" (
        if "%ii"=="DESCRIPT.ION" set description=Contains file descriptions as used by 4NT
        if "%ii"=="%based%.zip"  set description=Compressed copy of entire directory
    )

    iff exist "%base_name%.html" then (
       if "%description"=="" set description=%base_name.html
       echo %=<TD%=>%=<A HREF="%base_name.html"%=>%description%%=</A%=>%=</TD%=> >>%f
    )
    else
        echo %=<TD%=>%description%=</TD%=> >>%f
    endiff
    echo %=</TR%=> >> %f
    set n=%@inc[%n]
  )
  echo %=</TABLE%=> >>%f
  echo %=<P%=>[%n files indexed on %@makedate[%@date[%_date],4] at %_time >> %f
  echo by %=<BIG%=>%=<A HREF="http://jpsoft.com/"%=>4NT!%=</A >> %f
  echo %=>%=</BIG%=> ] >> %f
  echo %=<P%=> >> %f


text >> %f
<CENTER>
<P>
<INPUT type="button" value="Click here to go back" onClick="history.back()"/>
</P>
</CENTER>
<HR/>

<SMALL>
Last Modified<?php print date("F j, Y h:i:s A T", filemtime($PATH_TRANSLATED));?>
&copy; 1999-<?php print date("Y");?> Andrew Pitonyak
</SMALL>
</BODY>
</HTML>
endtext

  echo %n files indexed on %ymd at %_time

:done